固定処理を見直してみませんか？

メルマガ発行内容

＜固定処理を見直してみませんか？＞
どうも、三流プログラマーのＫｅｎ３です。

こんにちは、三流プログラマーのＫｅｎ３です。

今回は、私がやっと気が付いたことを書きたいと思います。

/*
 * １. 今日の狙い・・・
*/

私がやっと気が付いたこと？
^^^^^^^^^^^^^^^^^^^^^^^^^^
どんなこと？
くだらないことでしょ・・・と話を引っぱって置いて、

/*
 * ２．値を受け取り、処理を行う、そんな作りにする
*/

私が、関数作りヘタだなぁと自分で思ったことがあって、
少し前のメルマガで、ftp.exeを使用して、サーバーにファイルを書き込む、
そんな処理を作ってました。

Sub test()

    Dim strPNAME As String   'パラメーターファイル名
    Dim nFNO     As Integer  'ファイル番号

    strPNAME = ThisWorkbook.Path & "\ftptest.txt" 'ファイル名作成
    nFNO = FreeFile  '空いてるファイル番号を取る

    Open strPNAME For Output As #nFNO 'ファイルを新規作成

    'データ書き込み
    Print #nFNO, "open plaza14.mbn.or.jp" 'openホスト名
    Print #nFNO, "user ken3 XXXXXX←パス" 'userコマンド ユーザー名 パスワード
    Print #nFNO, "cd www"
    Print #nFNO, "pwd"
    Print #nFNO, "get index.html " & ThisWorkbook.Path & "\index.html"

    Close #nFNO  '開いたら閉じようね
    
    'shellでＦＴＰを起動 -nのオプションを付ける
    Shell "ftp -n -s:" & strPNAME

End Sub

みたいに、作ってましたが、
    Print #nFNO, "open plaza14.mbn.or.jp" 'openホスト名
など、ホスト名は、プログラムに埋め込み、
    Print #nFNO, "user ken3 XXXXXX←パス" 'userコマンド ユーザー名 パスワード
    Print #nFNO, "get index.html " & ThisWorkbook.Path & "\index.html"
などのファイル名も、そのまま書いてました。

まぁ、Constで定数を宣言なんて書いた時期もありましたが、
Const strHOST = "plaza14.mbn.or.jp"
として、
Print #nFNO, "open " & strHOST
と書く方法もあると思います。

必要な固定データをConst宣言して、変更を容易にする。
その方法もありなのですが、
必要なデータは変数で、受け取るようにする。
^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
この作りにしているほうが、流用性・汎用性があがることに最近やっと気が付く。

'ホスト名,ユーザー名、パスワード,ディレクトリ,書き込みファイル
'を受け取り、ftp.exeを起動して、ファイルをUPLOADする
Sub ftp_upfile(strHNAME As String, _
               strUSERNAME As String, _
               strPASS As String, _
               strDIR As String, _
               strUPFILE As String)

End Sub
このように、引数を受け取るように関数化して、

Sub TEST()

    Dim strFILENAME As String  'ファイル名受け取り用

    'ファイル名を選択する
    strFILENAME = Application.GetOpenFilename

    'プログラムの中にパスワード埋め込むのよくないけど
    '作った関数をコールする
    Call ftp_upfile("ftp.xxxx.jp", "username", "pass", "data/pc/", strFILENAME)

End Sub

とメインのルーチンで呼ぶ、すると、変更やテストも容易です。
さらにTESTのメインルーチンでConstを使い、

Sub TEST()
    Const strHOST = "ftp.xxxx.jp"
    Const strUSER = "username"
    Const strPASS = "pass"
    Const strUPDIR = "data/001/"

    Dim strFILENAME As String  'ファイル名受け取り用

    'ファイル名を選択する
    strFILENAME = Application.GetOpenFilename

    '作った関数をコールする
    Call ftp_upfile(strHOST, strUSER, strPASS, strUPDIR, strFILENAME)
End Sub

これが、いいんだなぁ、、、とやっと感じました。
※皆さんからみれば、当たり前かもしれませんが。

--- 余談 作成した、Ftp.exeを使ったサンプル ----
'ホスト名,ユーザー名、パスワード,ディレクトリ,書き込みファイル
'を受け取り、ftp.exeを起動して、ファイルをUPLOADする
Sub ftp_upfile(strHNAME As String, _
               strUSERNAME As String, _
               strPASS As String, _
               strDIR As String, _
               strUPFILE As String)

    Dim strPNAME As String   'パラメーターファイル名
    Dim nFNO     As Integer  'ファイル番号

    'パラメータファイル名をブック位置\ftppara.datとする
    strPNAME = ThisWorkbook.Path & "\ftppara.dat" 'ファイル名作成
    
    'ファイルを新規作成する
    nFNO = FreeFile  '空いてるファイル番号を取る
    Open strPNAME For Output As #nFNO 'ファイルを新規作成

    'コマンドデータを書き込む
    Print #nFNO, "open " & strHNAME  'open ホスト名
    Print #nFNO, "user " & strUSERNAME & " " & strPASS 'user ユーザー名 パスワード
    Print #nFNO, "cd " & strDIR      'cd xxxx 書き込みディレクトリへ移動
    Print #nFNO, "put " & strUPFILE  'put ファイル名 で、ファイルをアップする
    Print #nFNO, "quit"              'bay で コマンド終了

    'ファイルを閉じる(作成が終了したので)
    Close #nFNO  '開いたら閉じようね
    
    'shellでＦＴＰを起動 -n,-s:ファイル名 のオプションを付ける
    Shell "ftp -n -s:" & strPNAME

End Sub

※問題点は、スペースありのフォルダー名と複数ファイルのＵＰです。
　まだまだ、改良の余地があるけど、
　引数で受け取るようにすると、変更するときもデータを気にしないでＯＫなので、
　楽ですね。
　データの管理部分と処理部分を分ける、基本と言われそうだけど、
　なんかやっと気が付いた感じがします。
　（なんていいつつ、次作るときは、今の心境を忘れて昔に戻ったりして）

/*
 * ３．過去の資産の見直し
*/

って、ことは、
私が過去に作ったモージュールは、
データ部分と処理部分が分かれていない、そんなモジュールが多いと思う。
※過去の自分の弁護すると（笑）、テストとしては一緒のほうが見やすいんだけど。

皆さんも、過去の資産を見直してみてください。
私も、見直して、汎用性のあるモジュールの例を書いてみたいと思います。

/*
 * ４．終わりの挨拶
*/

今回は、
やっと気が付いた、データと処理を分ける。
そんな話でした。
※ツール作りを目標にしているので、
　汎用性のある部品を作っていきたいですね。

こんな方法もあるってことで、何か読者の心に残れば、うれしいです。
＊私の独り言をうまく消化してくださいね。

最近、偉そうで感じ悪いと評判の不親切なＫｅｎ３でした。
~~~~~~~(↑オイオイ、また攻撃食らうぞ（笑）)

ページフッター

ここまで、読んでいただきどうもです。ここから下は、三流君のホームページの紹介・案内です
目的の情報が見つかったか？少々心配しつつ、、、

種類別のリンク や 広告など

Blogとリンク:[三流君の作業日記]/ [VBAやASPのサンプルコード]/ 広告-[通販人気商品の足跡]