[VBAでIE操作(TOP)]
[IE関係記事一覧]
[IE関係ブクマ]
[三流君(TOP)]
[VBA(TOP)]
はじめは[WebBrowserを参照設定]から入り
小さな[IE操作のサンプル]でTEST
次に[少し大きなIEを使ったサンプル]
にチャレンジしたり
手探りで[ヘルプ IEのオブジェクトを探る]←迷ってみたり
よく使う.Document:の解説
[.Forms]で入力処理
[.Links]でリンク情報取得
[.Images]で画像の情報
[.Frames]でフレーム処理
[.Script]でスクリプト処理
IE,WebBrowser:
[IE プロパティ(各種設定)]
[IE メソッド(イロイロな動作)]
[IE イベント(発生後処理)]


三流君VBAでIE操作 画像・イメージ操作 Document.Images

挨拶:VBAで(ExcelやAccessなどから)InternetExplorer WebBrowserを操作してみたいと思います。
Document.Imagesで、画像・イメージにアクセスできるので、イロイロと操作してみたいと思います。

一覧、頭から Document.Images にアクセスしてみた。

Document.Images で イメージのオブジェクトにアクセスできたので、
Dim objIMG As HTMLImg 'イメージ、図
と変数を宣言してから、下記のループで1つ1つ取り出し使ってみました。
For n = 0 To objDOC.images.Length - 1 'イメージ数ループする。
Set objIMG = objDOC.images(n) 'n番目のイメージを代入
↑あとは、それっぽい、プロパティを書き出してみました。
.src が URL で .Titleが呼んで字のごとくタイトルでした。
サンプルを動かしながら、確認してみてください。

下記、サンプルです。Excel2003 OS:XP SP3 IE8 でテストしました。
まずは、実行して遊んでみてください。
'参照設定 Microsoft Internet Controls(Microsoft Browser Helpers)
'Microsoft HTML Object Library の 2つを忘れずに

'参照設定の方法は、 http://www.ken3.org/cgi-bin/group/vba_ie_object.asp をみてください。

Sub ie_test_img_list()  'イメージ 画像のリスト 一覧を作る
    
'目的のURLを入力する。(URLを指定する)
    Dim strURL As String  'URL入力用
    strURL = InputBox("URLを指定", "URL入力", "http://ie.vba-ken3.jp/test/")

    '結果表示エリアをクリア
    Rows("6:999").Delete Shift:=xlUp

'IEのオブジェクトを新規で作り、表示サイズと場所を調整する。
    Dim objIE   As InternetExplorer  'IEオブジェクト参照用
    Set objIE = CreateObject("InternetExplorer.application") 'IEのオブジェクトを作る
    objIE.Visible = True '見えるようにする(お約束)
    
    'IE 画面サイズの調整(表示場所とサイズ)
    objIE.FullScreen = False '= Trueで最大化します。
    objIE.Top = 200    '左上 Y 表示場所の指定
    objIE.Left = 100   '左上 X
    objIE.Width = 800  '横の幅
    objIE.Height = 600 '縦の高さ

'目的のページを表示する
    '指定したページを表示
    objIE.navigate strURL   '文字列でURLを渡す

    '表示完了を待つ .readyState と .Busy を見る
    While objIE.readyState <> READYSTATE_COMPLETE Or objIE.Busy = True 'IEがBusyの間 待つ
        DoEvents
    Wend
    DoEvents

'表示されたHTML文章 ドキュメント にアクセスして、画像の情報をセルに書き込む
    Dim n As Integer 'n番目のカウンター変数
    Dim y As Integer 'Y行目のカウンター変数
    
    'ドキュメント、HTML文章にアクセスする
    Dim objDOC As HTMLDocument
    Set objDOC = objIE.document 'IEの文章をセット

    Range("A6") = "URL = " & objDOC.URL
    Range("A7") = "ページのタイトルは = " & objDOC.Title

    'イメージ、画像を探る
    Dim objIMG As HTMLImg  'イメージ、図

    y = 10
    Cells(y, "A") = "images.Length は(イメージの数は) " & objDOC.images.Length
    y = y + 1
    
    '見出しを付ける。
    Cells(y, "A") = "no(n番目)"
    Cells(y, "B") = "'.src (URL)"   'URL
    Cells(y, "C") = "'.Title" 'タイトル
    Cells(y, "D") = "'.outerHTML" 'HTML
    y = y + 1
    
    'イメージを1つ1つ取り出し、処理する。
    For n = 0 To objDOC.images.Length - 1 'イメージ数ループする。
        Set objIMG = objDOC.images(n)   'n番目のイメージを代入
        Cells(y, "A") = n
        Cells(y, "B") = "'" & objIMG.src   'URL
        Cells(y, "C") = "'" & objIMG.Title 'タイトル
        Cells(y, "D") = "'" & objIMG.outerHTML 'HTML
        
        y = y + 1  '次の行へ
    Next

'後始末
    '終了処理 テストの時は、↓確認して、残しておくと便利ですよ。
    If MsgBox("IEを閉じますか?", vbYesNo) = vbYes Then '終了確認
        objIE.Quit  '.Quitで閉じる
    End If
    '使用したオブジェクト変数もキレイにしてね。
    Set objIMG = Nothing
    Set objDOC = Nothing
    Set objIE = Nothing

End Sub

試行錯誤の動画:[Document.Images にアクセスしてみた As HTMLImg]

画像のURLを指定して、ダウンロードしてみた。

無事、画像の一覧・リストが作れたので、ダウンロードしてみたいと思います。
webからファイルを落とすには [URLDownloadToFile を 使いファイルをダウンロード] を 使うと比較的簡単です。
組み込んで、使ってみました

'OS:XP SP3 IE8 Excel2003でテスト。
'参照設定 Microsoft Internet Controls(Microsoft Browser Helpers)
'Microsoft HTML Object Library の 2つを忘れずに
'参照設定の方法は、 http://www.ken3.org/cgi-bin/group/vba_ie_object.asp をみてください。

'URLDownloadToFile API from URLMON.
Private Declare Function URLDownloadToFile Lib "urlmon" Alias _
"URLDownloadToFileA" (ByVal pCaller As Long, ByVal szURL As String, ByVal _
szFileName As String, ByVal dwReserved As Long, ByVal lpfnCB As Long) As Long
'↑ソースの一番上に宣言文を書き込んでください。

Sub ie_test_img_download()  'イメージ 画像のリスト 一覧を作り ダウンロード
    
'目的のURLを入力する。(URLを指定する)
    Dim strURL As String  'URL入力用
    strURL = InputBox("URLを指定", "URL入力", "http://ie.vba-ken3.jp/test/")

    '結果表示エリアをクリア
    Rows("6:999").Delete Shift:=xlUp

'IEのオブジェクトを新規で作り、表示サイズと場所を調整する。
    Dim objIE   As InternetExplorer  'IEオブジェクト参照用
    Set objIE = CreateObject("InternetExplorer.application") 'IEのオブジェクトを作る
    objIE.Visible = True '見えるようにする(お約束)
    
    'IE 画面サイズの調整(表示場所とサイズ)
    objIE.FullScreen = False '= Trueで最大化します。
    objIE.Top = 200    '左上 Y 表示場所の指定
    objIE.Left = 100   '左上 X
    objIE.Width = 800  '横の幅
    objIE.Height = 600 '縦の高さ

'目的のページを表示する
    '指定したページを表示
    objIE.navigate strURL   '文字列でURLを渡す

    '表示完了を待つ .readyState と .Busy を見る
    While objIE.readyState <> READYSTATE_COMPLETE Or objIE.Busy = True 'IEがBusyの間 待つ
        DoEvents
    Wend
    DoEvents

'表示されたHTML文章 ドキュメント にアクセスして、画像の情報をセルに書き込む
    Dim n As Integer 'n番目のカウンター変数
    Dim y As Integer 'Y行目のカウンター変数
    
    'ドキュメント、HTML文章にアクセスする
    Dim objDOC As HTMLDocument
    Set objDOC = objIE.document 'IEの文章をセット

    Range("A6") = "URL = " & objDOC.URL
    Range("A7") = "ページのタイトルは = " & objDOC.Title

    'イメージ、画像を探る
    Dim objIMG As HTMLImg  'イメージ、図

    y = 10
    Cells(y, "A") = "images.Length は(イメージの数は) " & objDOC.images.Length
    y = y + 1
    
    '見出しを付ける。
    Cells(y, "A") = "no(n番目)"
    Cells(y, "B") = "'.src (URL)"   'URL
    Cells(y, "C") = "'.Title" 'タイトル
    Cells(y, "D") = "'.outerHTML" 'HTML
    y = y + 1
    
    'イメージを1つ1つ取り出し、処理する。
    For n = 0 To objDOC.images.Length - 1 'イメージ数ループする。
        Set objIMG = objDOC.images(n)   'n番目のイメージを代入
        Cells(y, "A") = n
        Cells(y, "B") = "'" & objIMG.src   'URL
        Cells(y, "C") = "'" & objIMG.Title 'タイトル
        Cells(y, "D") = "'" & objIMG.outerHTML 'HTML
        
        'ダウンロード処理を呼ぶ
        Call get_url_file(objIMG.src) 'URLを渡す
        
        y = y + 1  '次の行へ
    Next

'後始末
    '終了処理 テストの時は、↓確認して、残しておくと便利ですよ。
    If MsgBox("IEを閉じますか?", vbYesNo) = vbYes Then '終了確認
        objIE.Quit  '.Quitで閉じる
    End If
    '使用したオブジェクト変数もキレイにしてね。
    Set objIMG = Nothing
    Set objDOC = Nothing
    Set objIE = Nothing

End Sub

'URLを受け取り、ファイルをダウンロードする
'関数内でURLからファイル名を作成する(/を探す)
' 詳細は http://www.ken3.org/vba/backno/vba120.html を見てください。
Sub get_url_file(strURL As String)

    Dim strFNAME As String  'ダウンロード先(パス+ファイル名)
    Dim strWORK  As String  '後ろから/を探し、ファイル名を取り出す
    Dim returnValue
    Dim n As Integer

    'ファイル名を取り出す
    For n = Len(strURL) To 1 Step -1 '後ろから/を探す
        If Mid(strURL, n, 1) = "/" Then
            Exit For  '/が見つかったらループを抜ける
        End If
    Next n
    strWORK = Mid(strURL, n + 1) '/の次からファイル名なのでn+1から
    
    'ファイル名をブックのパス+\+取り出したファイル名とする
    strFNAME = ThisWorkbook.Path & "\" & strWORK
    'strFNAME = "C:\DATA\AAA\" & strWORK と固定のパスでもOKだけど

    'URLDownloadToFile API をコールする
    returnValue = URLDownloadToFile(0, strURL, strFNAME, 0, 0)

End Sub

なんとか、画像ファイルをダウンロードすることができました。

試行錯誤の動画:[Document.Images から 画像のファイル名を取り出し DownLoad してみた]

逃げるように 終わりの挨拶

入り口を間違えないで、みなさんは参照設定から行ってくださいね。
※まだまだ、確認すること、やることいっぱいだぁ。。。



[#BackNoLink][ページ内のTOPへ戻る]

過去のメールマガジンのリンクが長かったので、下記に移動しました。
[IE操作 メルマガ 一覧]
よろしくお願いします。


改版履歴 更新情報:過去のIE操作の解説はこちら↓(IE6+XP,IE7+XPの古い記事もアリ)
2009-12-01:[過去の解説 vba_ie_20091201.asp]
2009-06-01:[過去の解説 vba_ie_20090601.asp]
2009-02-01:[過去の解説 vba_ie_20090201.asp]
2008-05-01:[過去の解説 vba_ie_20080501.asp]
2007-08-31:[過去の解説 vba_ie_20070831.asp]
2007-05-20:[過去の解説 vba_ie20070520.asp]

2012-03-19:[過去の解説 vba_ie_20120319.html]
もあわせてみてください。
(↑もしかして書き直さない過去の解説の方がよかったかも?(笑))




[ページ内のTOPへ戻る]

ページフッター

ここまで、読んでいただきどうもです。ここから下は、三流君宛のメッセージ送信や 三流君のホームページの紹介・案内です
目的の情報が見つかったか?少々心配しつつ、、、

感想や質問・要望・苦情など 三流君へメッセージを送る。[#QA_MESSAGE]


あなたのお名前(ニックネーム):さん
返信は?:

アドレス:に返事をもらいたい
感想や質問↓:



(感想や質問・要望・苦情はHPで記事に載せることがあります。)
例:[XXXXさんへ回答例]←みたいに回答していたり...

急ぎで連絡がほしい、そんな時は:[twitter三流君]に気軽に連絡してください。




[三流君(TOPへ)] / [VBAで楽しく] / [記事一覧]
カスタム検索




広告

リンク広告
  1. --[Windows 自動ログイン control userpasswords2 や netplwiz]
  2. --[【ガチャ】モンスト 3500万人記念!!オーブ0ガチャ]
  3. --[Access コンボボックスを使ってみた]
  4. --[ Windows10 OSのフルバックアップ システムイメージバックアップ]