IE 認証ページへのアクセス、basci認証ページって？

概要:

ヘッダーに
"Authorization: Basic 変換したコード"
と基本認証のコードを埋め込み、Basic認証のページをIEで開いてみました。
    'テスト用の認証ページに飛ぶ
    Const strURL = "http://www.kurokiya.sake-ten.jp/zzz/"
    Const strHEAD = "Authorization: Basic bWFpbG1hZ2E6Z3Vlc3Q= " & vbCrLf
    objIE.navigate2 strURL, , , , strHEAD
たんに埋め込んだコードをヘッダーで送っているだけです。

　はじめまして。“み”と申します。
　三流君さんの[No.159 IE 認証ページへのアクセス、basci認証ページって？]という記事を元に基本認証で守られたcsvファイルの取得を目指して試行錯誤しているものです。（id、パスワードともに既知）
　windows98ではnavigate2メソッドでうまくエクセルファイル上で開いてくれるのですが、xpではIE上でエクセルファイルとして？開いてしまうためどうもその後に続ける事ができません。
　navigate2メソッドの直後にopenメソッドを入れると開いたり同名はだめと出たりで動作が不安定になってしまいます。
　何とかうまい方法、もしくはそのために必要な資料等を教えていただけませんでしょうか。
　お願いいたします

基本認証が不要の場所、通常の場所にcsvファイルを置いた時はどうなりますか？(条件を基本認証とcsvファイルの２つから１つに切り分けてみる)
もしも、csvファイルだけでも正しく開けない問題だったら、
IE CSV 開く
の３つでGoogle検索
http://www.google.co.jp/search?sourceid=navclient&hl=ja&ie=UTF-8&rls=GGLG,GGLG:2005-37,GGLG:ja&q=IE+CSV+%E9%96%8B%E3%81%8F

[IE] CSV ファイルへのアクセス時に確認のダイアログが開かない
http://support.microsoft.com/default.aspx?scid=kb;ja;831778

[PRB] .rtf または .csv ファイルの閲覧時にダイアログ ボックス内の [開く] ボタンが無効になる
http://support.microsoft.com/?scid=kb;ja;318761&spid=1743&sid=62

XP SP2適用後にIEでCSVファイルがダウンロード時に保存先指定できない？
http://bbs.hotfix.jp/ShowPost.aspx?PostID=1830

なんて感じでOSや環境の問題がありそうですが・・・
通常開けて、基本認証がからむ時だけ開けないなら、、、う〜ん、私もお手上げです。
何か原因らしき処理を見つけたらまた書き込みます。

早期に解決されることを願いつつ失礼します。

PS.フィールド名(先頭行)にＩＤが入っているcsvファイルだと、何か不具合があった記憶もありますが、、、、※フィールド名にIDはありますか？

ぶしつけで下手な質問に対し丁寧な回答ありがとうございます
> 基本認証が不要の場所、通常の場所にcsvファイルを置いた時はどうなりますか？
>(条件を基本認証とcsvファイルの２つから１つに切り分けてみる)
　それは特に問題はないです
　手で基本認証のIDとパスワードは入力した場合も特に不具合は
ないです。workbooks.open "URL" で開いたときも基本認証を手で
入力すれば普通に（IE上のエクセルではなく）エクセルで開けます。
　むしろ問題としては手での入力を代行してなおかつIE上ではなく
エクセル上で何とか開きたいなというあたりで引っかかっています。
（もしくはIE上で開かれているエクセルからの情報の取得ができれば？）

> PS.フィールド名(先頭行)にＩＤが入っているcsvファイルだと、
>何か不具合があった記憶もありますが、、、、
>※フィールド名にIDはありますか？
確かにcsvファイルの"a1"に基本認証で問われるIDは入っていますが・・・

以下が試したものです。（ほぼKen3さんのコードそのままですが・・・）

'BASE64でユーザーＩＤ：パスワードを変換して開く
Private Const ID '基本認証用ID文字列
Private Const pas '基本認証用パスワード文字列
Private Const Path '対象ファイルのURL文字列
Sub test()
Dim objIE As Object 'ＩＥオブジェクト参照用

'インターネットエクスプローラーのオブジェクトを作る
Set objIE = CreateObject("InternetExplorer.application")
objIE.Visible = True '見えるようにする(お約束)

'テスト用の認証ページに飛ぶ
Const strURL = Path
Dim strHEAD As String

'ID:passwordをBASE64変換してヘッダ情報を作成する
strHEAD = "Authorization: Basic " & base64(ID & ":" & pas) & vbCrLf
objIE.navigate2 strURL, , , , strHEAD
'表示終了まで待つ
Do While objIE.Busy = True
'何もしないループ（笑）
DoEvents
Loop
'エクセルで基本認証済みのものを横取り？
'IE側は中の表示がない同名？の窓が出てくる
Workbooks.Open strURL
'ただ以前対象のファイルが開かれた事があったりすると
　　'IE側で先に開かれてOpenメソッドが失敗しましたとなる
End Sub

実験用に基本認証でくくられている場所に有るcsvファイルを用意できればいいのですが・・・

ごめんなさい、真逆だったのですね。
※私の回答はIEで開けない時？で、質問はIEで開かせたくない、Excel内で開きたいでしたか・・・

基本認証の.csvを一時的にローカルファイルにダウンロードして、
Workbooks.Open "c:\temp.csv"
で開こうと思い、少しチャレンジしてみました。

パターン的にサンプルがほしい時は、
site:www.microsoft.com Web 基本認証 "End Sub"
と
キーワードを書いた後に、"End Sub"で探すとよくサンプルが見つかります。
※VBAやVBのプログラムはSub 〜 End Sub なので。

XML と Exchange 2000 による Web アプリケーション開発
http://www.microsoft.com/japan/msdn/exchange/exchange2000/devwebapps.asp
で
XMLHTTP によるコードの記述
XMLHTTP .OPEN　があることを知る。

で次に、
site:www.microsoft.com xmlhttp open

Web ページがアクセス可能かどうかを確認する方法はありますか
http://www.microsoft.com/japan/technet/scriptcenter/resources/qanda/feb05/hey0222.mspx

Set objHTTP = CreateObject("MSXML2.XMLHTTP") 
objHTTP.Open "GET", strURL, FALSE
objHTTP.Send

Wscript.Echo(objHTTP.statusText)

とか

Set objHTTP = CreateObject("MSXML2.XMLHTTP") 
objHTTP.Open "GET", strURL, FALSE
objHTTP.Send

Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objFile = objFSO.CreateTextFile("script_center.htm", ForWriting)
objFile.Write objHTTP.ResponseText
objFile.Close

なんて感じで、何か保存してますね。

次は、MSXML2.XMLHTTPの詳細が知りたいです。
※基本認証可能か？知りたいです。

site:www.microsoft.com XMLHTTP .Open .Send

[HOWTO] XMLHTTP を使用してバイナリ ストリームを送信する方法
http://support.microsoft.com/default.aspx?scid=kb;ja;296772
ここに、
.setRequestHeader
とヘッダー情報のセットが載っていたりする。。。

さてと、
Sub cccc()

    Dim objIE As Object 'ＩＥオブジェクト参照用

    'インターネットエクスプローラーのオブジェクトを作る
    Set objIE = CreateObject("InternetExplorer.application")
    objIE.Visible = True '見えるようにする(お約束)

    'テスト用の認証ページに飛ぶ
    Const strURL = "http://www.kurokiya.sake-ten.jp/zzz/test.csv"
    Const strHEAD = "Authorization: Basic bWFpbG1hZ2E6Z3Vlc3Q= " & vbCrLf

    objIE.navigate2 strURL, , , , strHEAD

    '表示終了まで待つ
    Do While objIE.Busy = True
        '何もしないループ（笑）
        DoEvents
    Loop

    'XMLHTTPでローカルにダウンロードする
    Dim objHTTP As Object
    
    Set objHTTP = CreateObject("MSXML2.XMLHTTP")
    objHTTP.Open "GET", strURL, False
    objHTTP.setRequestHeader "Authorization", " Basic bWFpbG1hZ2E6Z3Vlc3Q= " & vbCrLf
    objHTTP.Send

    MsgBox objHTTP.ResponseText

End Sub

とする、それらしく画面に出た・・と思ったら文字化けしてる・・・
objHTTP.ResponseText
を保存して開きたいよなぁ。もしくはobjHTTP.ResponseTextを直接シートに貼り付けたいんだけどなぁ・・・

> 実験用に基本認証でくくられている場所に有るcsvファイルを用意できればいいのですが・・・

私の通販用のサイトですが、
    Const strURL = "http://www.kurokiya.sake-ten.jp/zzz/test.csv"
    Const strHEAD = "Authorization: Basic bWFpbG1hZ2E6Z3Vlc3Q= " & vbCrLf
ここ上記の値でテストで使ってみてください。

もしソースをUPする時は、今回みたいに気をつけてくださいね。※本番用CODEをUPしないでね。

文字コードの件、少々探ってみます。

途中経過ですが、何かの参考となれば幸いです。

下記のような感じで、一時csvをローカルに保存して、
開いてみました。

Sub dddd()

    Dim objIE As Object 'ＩＥオブジェクト参照用

    'インターネットエクスプローラーのオブジェクトを作る
    Set objIE = CreateObject("InternetExplorer.application")
    objIE.Visible = True '見えるようにする(お約束)

    'テスト用の認証ページに飛ぶ
    Const strURL = "http://www.kurokiya.sake-ten.jp/zzz/test.csv"
    Const strHEAD = "Authorization: Basic bWFpbG1hZ2E6Z3Vlc3Q= " & vbCrLf

    objIE.navigate2 strURL, , , , strHEAD

    '表示終了まで待つ
    Do While objIE.Busy = True
        '何もしないループ（笑）
        DoEvents
    Loop

    'XMLHTTPでローカルにダウンロードする
    Dim objHTTP As Object
    
    Set objHTTP = CreateObject("MSXML2.XMLHTTP")
    
    objHTTP.Open "GET", strURL, False  'URLとモードを教えてあげる
    
    'ヘッダー情報を送る  :(コロン)が入っていないことに注意・・これでハマった。
    objHTTP.setRequestHeader "Content-Type", " text/xml; charset=UTF-8 "
    objHTTP.setRequestHeader "Authorization", " Basic bWFpbG1hZ2E6Z3Vlc3Q= " & vbCrLf
    '↑Authorization:のコロンは必要なし・・・
    
    objHTTP.Send  'ここでデータがサーバーへ送られる と 同時にレスポンスが返る？？
    'ここに読めなかったときのエラー処理を書きたいが・・・どうする？？？

    'メモリに読み込めたら、ファイルに落としたいので、
    'ADODB.Stream で 読み込んだデータを書き込む
    Const adTypeBinary = 1
    Const adSaveCreateOverWrite = 2

    Dim objA As Object  'ADODB.Stream
    Dim strFILENAME As String  'ファイル名
    
    strFILENAME = ActiveWorkbook.Path & "\tmp.csv" '現在のブック+tmp.csvとする
    
    Set objA = CreateObject("ADODB.Stream")
    objA.Type = adTypeBinary
    objA.Open
    objA.Write objHTTP.responseBody  'Streamに本文をそのまま代入
    'そしてファイル.SaveToFileで書き込む
    objA.SaveToFile strFILENAME, adSaveCreateOverWrite
    '後始末
    objA.Close  '開けたら閉めようね。
    Set objADOS = Nothing  '変数も後始末
    Set objHTTP = Nothing  'XMLオブジェクトも用なし
    objIE.Quit 'IEも用済みなので消えてもらう
    Set objIE = Nothing  '変数も後始末

    'やっとテンポラリができたので、
    'ローカルに落ちたcsvをOpenする
    Workbooks.Open strFILENAME  'テンポラリのCSVを開きます

End Sub

もし、使えるようなら、エラー処理や一時ファイルの削除など肉付けをして使ってみてください。

何かの参考となれば幸いです。

あっヤバイ
CreateObject("ADODB.Stream")
がWin98だと使えないや・・・
UPしたコードは忘れてください(笑)

よく考えたらobjIEとか必要なかった・・・スミマセン。

Sub eeee()

    'XMLHTTPでローカルにダウンロードする
    Dim objHTTP As Object
    Const strURL = "http://www.kurokiya.sake-ten.jp/zzz/test.csv"
    
    Set objHTTP = CreateObject("MSXML2.XMLHTTP")
    
    objHTTP.Open "GET", strURL, False  'URLとモードを教えてあげる
    
    'ヘッダー情報を送る  :(コロン)が入っていないことに注意・・これでハマった。
    objHTTP.setRequestHeader "Content-Type", " text/xml; charset=UTF-8 "
    objHTTP.setRequestHeader "Authorization", " Basic bWFpbG1hZ2E6Z3Vlc3Q= " & vbCrLf
    '↑Authorization:のコロンは必要なし・・・
    
    objHTTP.Send  'ここでデータがサーバーへ送られる と 同時にレスポンスが返る？？
    'ここに読めなかったときのエラー処理を書きたいが・・・どうする？？？

    'メモリに読み込めたら、ファイルに落としたいので、
    'ADODB.Stream で 読み込んだデータを書き込む
    Const adTypeBinary = 1
    Const adSaveCreateOverWrite = 2

    Dim objA As Object  'ADODB.Stream
    Dim strFILENAME As String  'ファイル名
    
    strFILENAME = ActiveWorkbook.Path & "\tmp.csv" '現在のブック+tmp.csvとする
    
    Set objA = CreateObject("ADODB.Stream")
    objA.Type = adTypeBinary
    objA.Open
    objA.Write objHTTP.responseBody  'Streamに本文をそのまま代入
    'そしてファイル.SaveToFileで書き込む
    objA.SaveToFile strFILENAME, adSaveCreateOverWrite
    '後始末
    objA.Close  '開けたら閉めようね。
    Set objADOS = Nothing  '変数も後始末
    Set objHTTP = Nothing  'XMLオブジェクトも用なし
    
    'やっとテンポラリができたので、
    'ローカルに落ちたcsvをOpenする
    Workbooks.Open strFILENAME  'テンポラリのCSVを開きます

End Sub

Win98と2000/XPでプログラムが切り替えられれば、、、う〜ん。。。

解答していただいたものをもとに一週間ほど調べたり考えたりしたいと思います。

有難うございました。

[三流君 VBAでWebBrowser IEを操作する] / [三流君 VBAで楽しくプログラミング] / [AB型の変わり者 三流プログラマー Ken3 三流君Top]

大分類:[Document.Forms(入力処理)] / [Document.Links(リンク情報)] / [Document.Images(画像情報)] / [Document.Frames(フレーム処理)]
サンプル・例題:[過去のメルマガ記事一覧] / [少し大きなIE操作サンプル] / [小さなコードでIE操作の動作確認]

F1でヘルプを見たり、デバック時にDebug.Print使ったり、イミディエイト ウインドウで簡単な確認したり。
なれると当たり前に操作している方法が↓かなぁ。
[F1ヘルプ マクロ記録ほか]・・・基本のF1を押してヘルプを見る方法など
[実行時エラー、デバッグモード]・・・デバッグの流れを簡単に（ハマった時はツライけど）
[イミディエイト ウインドウ と Debug.Print]・・・プログラム作成時に便利なイミディエイト ウインドウ
[VBA ウォッチ式とSTOPを使ってみた]・・・STOPで止め、ウォッチ式でオブジェクトの中身を確認する方法など
[参照設定のお話]・・・設定すると便利な(設定しないと使えない)、参照設定のお話

項目別に↓にプログラマーの本音？それとも建て前？的な記事をまとめました。お探しのジャンルを選択してください。
[プログラムは心？ spirit]・・・プログラマー 心・気質・魂
[学ぶ study]・・・学習、技術の取得
[仕様書 doc]・・・仕様書・設計書関係の話

項目別に↓に人気の記事をまとめてみました。お探しのジャンルを選択してください。
[VBAでIE ウェブブラウザーを操作]・・・VBAでIE,WebBrowserを操作する サンプルです
[MSアクセス から エクセル を呼ぶ Excel.Application]・・・AccessからExcelを操作したりデータの書き出しなどです
[アウトルック メールの操作 Outlook.Application]・・・VBAからOutlookを使い、メール関係を処理するサンプルです
↑上記３つみたいなCreateObjectで他のアプリケーションを操作するサンプルが人気です。

Excel関係:
[エクセル ユーザーフォームを操作する]・・・エクセルでユーザーフォームを作成して入力などを行ってます
[エクセルからアクセスを操作する]・・・ExcelからAccessのマクロを起動してみました、
[エクセル関係 関数、その他]・・・その他Excel関係です

Access関係:
[アクセス ユーザーフォーム/サブフォーム 操作]・・・アクセスでフォームを使ったサンプルです
[アクセス レポート操作]・・・レポートを操作してみました
[アクセス クエリーやその他関数]・・・あまりまとまってませんが、スポット的な単体関数の解説です

その他：VBAの共通関数やテキストファイルの操作など
[テキストファイルの操作(Open,Close,Print,Input)]・・・普通のテキストファイルを使ったサンプルです

Blog:[三流君の作業日記]/ [objIEを使用したサンプルコードを見る]/ 広告-[通販人気商品の足跡]