[三流君] [VBAで楽しく] [VBA IE 操作]
−−> No.159 IE 認証ページへのアクセス、basci認証ページって?

IE 認証ページへのアクセス、basci認証ページって?

概要:

ヘッダーに
"Authorization: Basic 変換したコード"
と基本認証のコードを埋め込み、Basic認証のページをIEで開いてみました。
    'テスト用の認証ページに飛ぶ
    Const strURL = "http://www.kurokiya.sake-ten.jp/zzz/"
    Const strHEAD = "Authorization: Basic bWFpbG1hZ2E6Z3Vlc3Q= " & vbCrLf
    objIE.navigate2 strURL, , , , strHEAD
たんに埋め込んだコードをヘッダーで送っているだけです。

※メルマガ記事ではオブジェクトの参照設定をしていませんができれば、下記を参考に参照設定してください。
[Microsoft Internet Controls,Microsoft HTML Object Library を参照設定する](このほうが開発時、操作時に楽)
また、VistaとIE7の場合は、 [IE7 操作 Vistaで失敗]も参考にしてください。

リンク 分類: [Document(文章)からデータを取得] / [Form入力処理] / [Linkリンク情報] / [Image画像情報] / [Frameフレーム処理] サンプル: [IEを使ったVBAのサンプル] / [小さなVBAでIE操作のコード]

メルマガ発行内容

やっと、下記、メルマガで発行した内容です。何かの参考となれば幸いです。
過去のメルマガ[IE操作系の記事一覧]もヨロシクです。

<IE 認証ページへのアクセス、basci認証ページって?>

どうも、三流プログラマーのKen3です。 今回は、 IEでbasci認証ページへアクセスしてみたいと思います。 http://www.ken3.org/vba/lzh/vba159.lzh にサンプルweb159.xlsを圧縮しておきます、 Excel2000版ですが使ってみてください。 関連項目、 三流君VBAでInternetExplorer.Applicationを操作する(IE操作) http://www.ken3.org/cgi-bin/group/vba_ie.asp もヨロシクね。

/* * 1.今回のキッカケ */

昔、掲示板に下記の質問をもらいました。 ---------- 投稿時間:2004/03/28(Sun) 20:59 投稿者名:kuma san タイトル:Basic認証のページ はじめまして 今Vbsにてプログラムを作っているのですが ここのページはよく参考にしています。 1つどうしてもできないことがあって質問致します。 Basic認証のページのHTMLを保存するプログラムを書こうと思っているのですが、 id,passをきかれて、そこでsendkeysで{enter}をおくりたいのですが、どうも送る ことができず困っています。 何かこういった場合特別な方法があるのでしょうか?? ---------- 投稿時間:2004/03/31(Wed) 13:49 投稿者名:Ken3 タイトル:Re: Basic認証のページ Basic認証のページ user名とパスワードを入力する、ダイアログのことですよね。 たしか、sendkeysを使わなくてもよい方法がどこかに載っていたと思うので、少し 見てみますね。 ですが、期待しないでね。 マシーン壊れて、今、復旧中なので少々お待ちを。 ---------- マシーンは復旧しただろ?って自己突込みは置いといて、 今回は基本認証のページについて少し探りながら遊んでみます。

/* * 2.認証ページって何? */

会員の限定ページや、パスワードで管理したい秘密のページ、 そんなページがあります。 ありますじゃなくって、パスワードで管理されたページを作ることができます。 私の借りているNTTのホスティングサービスでは、 ユーザ認証(アクセス制限)の設定について http://www.ocn.ne.jp/myhosting/howto/6-3e-1.html みたいな感じで、簡単に設定可能でした。 試しに、zzzとディレクトリを作成して、 ユーザー名 mailmaga パスワード guest と設定してみました。 ↑簡単な設定方法(用意されたコントロールパネルを使用してみた) テストの前にいつもの宣伝。(オイオイ、やりすぎるとクレーム来るぞ?) 通常、下記のようなページを表示できます。 http://www.kurokiya.sake-ten.jp/GAME/index.html ← ゲームの通販 http://www.kurokiya.sake-ten.jp/idol/index.html ← アイドル関係 http://www.kurokiya.sake-ten.jp/DVD/index.html ← DVDの販売 新たな通販ページを作成中・・・みんなが見なくてもロボットが 読んでくれる事を期待して、リンクを載せるセコい技(笑) なんて、いつもの宣伝はほとほどにスルーして(スルーしなくて見てもいいけど) 基本認証を設定したzzz下記にアクセスすると http://www.kurokiya.sake-ten.jp/zzz/ useridとpasswordの確認画面が表示されます。 ユーザー名 mailmaga パスワード guest と入力して、ログインすることができます。 ↑basic認証の画面 少し駆け足でしたが、認証ページの設定と動作でした。 ※会員制のページも簡単に作れそうですね。 --- 補足 ---- 通常は、下記のようなファイルを作るらしいけど、知識が無くて、 NTTが用意したホスティングのコントロールパネルから設定しました。 .htaccess AuthUserFile /u/zzz/.htpasswd AuthGroupFile /dev/null AuthName Protected Area AuthType Basic <Limit GET POST> require user mailmaga </Limit> と .htpasswd mailmaga:J***********E ←*は私がつぶしてます、通常はパスワードが設定されてます って感じのファイルを自分で作るには、私は正直まだ勉強不足です。 そんなんじゃ・・・と思いつつ、日々の在宅業務や派遣先でイジメラレテタリ。 その他日記 http://blog.melma.com/00034126/?word=%5betc%5d

/* * 3.自動巡回の壁 IDとパスワードを聞いて来る */

話を戻して、 自動巡回だとパスワードを求められるページで処理が止まってしまいます。 fromに入れるタイプなら、submitなんてできるけど、 今回みたいな基本認証のダイアログが表示されると、それをかわしたいですよね。 '下記、パスワード入力で止まっている問題のプログラム 'ID:mailmaga password:guestを入力すると、動き出しますが、、、
Sub aaaa()

    Dim objIE As Object 'IEオブジェクト参照用

    'インターネットエクスプローラーのオブジェクトを作る
    Set objIE = CreateObject("InternetExplorer.application")
    objIE.Visible = True '見えるようにする(お約束)

    'テスト用の認証ページに飛ぶ
    objIE.navigate "http://www.kurokiya.sake-ten.jp/zzz/"

    '表示終了まで待つ
    Do While objIE.Busy = True
        '何もしないループ(笑)
        DoEvents
    Loop

    'テストでHTMLソースを取出す
    Dim strhtml As String
    strhtml = objIE.Document.all(0).innerHTML  '変数に代入
    MsgBox "ソースは" & strhtml & "です"

End Sub
そこをなんとか回避したいんだよね。 そこで、いつもの手抜き、腐った方法は、 http(s)://username:password@server/xxxxxx.xxx とURLにユーザー名とパスワードを含める方法なんだけど、 Internet Explorer 用の累積的なセキュリティ修正プログラム (832894) (MS04-004) http://www.microsoft.com/japan/technet/security/bulletin/MS04-004.asp で、この機能は悪用される恐れがあるので、パッチで埋められているらしい。 >注 : この更新プログラムをインストールすると、 >既定で “username:password@server” 形式の URL をサポートしなくなります。 だってさ、、 あらら、この形式で逃げようと思ってたのに・・・・残念。 ※ちゃんとやるかな今回は。

/* * 4.ヘッダーに認証コードを埋め込み開きたい */

キーワードを 基本認証 InternetExplorer.application の2つでマイクロソフトのHPを探すと、 下記が見つかります。 基本認証と Internet Explorer のクライアントを使用すると、 Single-Signで ソリューションを実装します。 http://support.microsoft.com/default.aspx?scid=kb;JA;837104 を見ると、 Authorization: Basic TG9jYWxVc2VyOkxvY2FsUGFzc3dvcmQ=\r\n 認証コード付きのヘッダで開けばいいのね。 ヘッダの指定かぁ。。。 http://support.microsoft.com/default.aspx?scid=kb;JA;174923 の [VB6] WebBrowseコントロールのPostDataパラメータの使い方 を見ると、 Navigate の仕様 URL (Universal Resource Locator) で指定したリソース、 またはフル パスで指定したファイルに移動します。 構文 object.Navigate URL [Flags,] [TargetFrameName,] [PostData,] [Headers] となっていて、[Headers]ヘッダーの指定が可能みたいです。 Authorization: Basic BASE64で変換したusername:passwordをここに書く といいのかぁ。BASE64の変換かぁ。 とりあえずBASE64の変換、わからなかったので、ツールをダウンロードして、 設定したユーザーとパスワードの組み合わせ mailmaga:guest を変換すると、 bWFpbG1hZ2E6Z3Vlc3Q= になるので、 ヘッダーに "Authorization: Basic bWFpbG1hZ2E6Z3Vlc3Q=" を指定する。
Sub bbbb()

    Dim objIE As Object 'IEオブジェクト参照用

    'インターネットエクスプローラーのオブジェクトを作る
    Set objIE = CreateObject("InternetExplorer.application")
    objIE.Visible = True '見えるようにする(お約束)

    'テスト用の認証ページに飛ぶ
    Const strURL = "http://www.kurokiya.sake-ten.jp/zzz/"
    Const strHEAD = "Authorization: Basic bWFpbG1hZ2E6Z3Vlc3Q= " & vbCrLf

    objIE.navigate2 strURL, , , , strHEAD

    '表示終了まで待つ
    Do While objIE.Busy = True
        '何もしないループ(笑)
        DoEvents
    Loop

    'テストでHTMLソースを取出す
    Dim strhtml As String
    strhtml = objIE.Document.all(0).innerHTML  '変数に代入
    MsgBox "ソースは" & strhtml & "です"

End Sub
これで、無事に基本認証のページを開くことができました。 ※ですが、リンクをクリックするとまたパスワードを聞いてくるので、  毎回指定しないとダメ?なのか?う〜ん、深いなぁ。 一回通ったらその後はOKだと楽なんだけどなぁ。

/* * 5.終わりの挨拶 */

IEのObjectで基本認証/Basic認証のページを開く、 ポイントは、 ヘッダーに "Authorization: Basic bWFpbG1hZ2E6Z3Vlc3Q=" とユーザーID:バスワードをBASE64変換したヘッダーを指定して開く、 そんな感じでした。 ツールに頼ったけど、BASE64の変換、探らないとなぁと思いつつ、 今回も中途半端にサヨナラです。 ※まぁ、パスワード変わらないなら、Const埋め込みでもいいのかなぁ・・・ プログラム作りは簡単で面白いなぁと感じるような 解説/メールマガジンを書きたいと思ってますが、 なかなか、うまくいってないです。(有料、無料とも上手くいってない・・・) 何か読者の心に残れば、うれしいです。 *私の独り言をうまく消化してくださいね。 いつも失敗?の負け組のKen3でした。 ~~~~~~~(↑オイオイ)

読者とのやりとり。


投稿時間:2006/05/01(Mon) 23:11
投稿者名:
Eメール:
URL :
タイトル:
基本認証とcsvファイル
 はじめまして。“み”と申します。
 三流君さんの[No.159 IE 認証ページへのアクセス、basci認証ページって?]という記事を元に基本認証で守られたcsvファイルの取得を目指して試行錯誤しているものです。(id、パスワードともに既知)
 windows98ではnavigate2メソッドでうまくエクセルファイル上で開いてくれるのですが、xpではIE上でエクセルファイルとして?開いてしまうためどうもその後に続ける事ができません。
 navigate2メソッドの直後にopenメソッドを入れると開いたり同名はだめと出たりで動作が不安定になってしまいます。
 何とかうまい方法、もしくはそのために必要な資料等を教えていただけませんでしょうか。
 お願いいたします

投稿時間:2006/05/02(Tue) 09:26
投稿者名:Ken3(管理者)
Eメール:
URL :
タイトル:
Re: 基本認証とcsvファイル
基本認証が不要の場所、通常の場所にcsvファイルを置いた時はどうなりますか?(条件を基本認証とcsvファイルの2つから1つに切り分けてみる)
もしも、csvファイルだけでも正しく開けない問題だったら、
IE CSV 開く
の3つでGoogle検索
http://www.google.co.jp/search?sourceid=navclient&hl=ja&ie=UTF-8&rls=GGLG,GGLG:2005-37,GGLG:ja&q=IE+CSV+%E9%96%8B%E3%81%8F

[IE] CSV ファイルへのアクセス時に確認のダイアログが開かない
http://support.microsoft.com/default.aspx?scid=kb;ja;831778

[PRB] .rtf または .csv ファイルの閲覧時にダイアログ ボックス内の [開く] ボタンが無効になる
http://support.microsoft.com/?scid=kb;ja;318761&spid=1743&sid=62

XP SP2適用後にIEでCSVファイルがダウンロード時に保存先指定できない?
http://bbs.hotfix.jp/ShowPost.aspx?PostID=1830

なんて感じでOSや環境の問題がありそうですが・・・
通常開けて、基本認証がからむ時だけ開けないなら、、、う〜ん、私もお手上げです。
何か原因らしき処理を見つけたらまた書き込みます。

早期に解決されることを願いつつ失礼します。

PS.フィールド名(先頭行)にIDが入っているcsvファイルだと、何か不具合があった記憶もありますが、、、、※フィールド名にIDはありますか?

投稿時間:2006/05/02(Tue) 10:52
投稿者名:
Eメール:
URL :
タイトル:
Re^2: 基本認証とcsvファイル
ぶしつけで下手な質問に対し丁寧な回答ありがとうございます
> 基本認証が不要の場所、通常の場所にcsvファイルを置いた時はどうなりますか?
>(条件を基本認証とcsvファイルの2つから1つに切り分けてみる)
 それは特に問題はないです
 手で基本認証のIDとパスワードは入力した場合も特に不具合は
ないです。workbooks.open "URL" で開いたときも基本認証を手で
入力すれば普通に(IE上のエクセルではなく)エクセルで開けます。
 むしろ問題としては手での入力を代行してなおかつIE上ではなく
エクセル上で何とか開きたいなというあたりで引っかかっています。
(もしくはIE上で開かれているエクセルからの情報の取得ができれば?)

> PS.フィールド名(先頭行)にIDが入っているcsvファイルだと、
>何か不具合があった記憶もありますが、、、、
>※フィールド名にIDはありますか?
確かにcsvファイルの"a1"に基本認証で問われるIDは入っていますが・・・

以下が試したものです。(ほぼKen3さんのコードそのままですが・・・)

'BASE64でユーザーID:パスワードを変換して開く
Private Const ID '基本認証用ID文字列
Private Const pas '基本認証用パスワード文字列
Private Const Path '対象ファイルのURL文字列
Sub test()
Dim objIE As Object 'IEオブジェクト参照用

'インターネットエクスプローラーのオブジェクトを作る
Set objIE = CreateObject("InternetExplorer.application")
objIE.Visible = True '見えるようにする(お約束)

'テスト用の認証ページに飛ぶ
Const strURL = Path
Dim strHEAD As String

'ID:passwordをBASE64変換してヘッダ情報を作成する
strHEAD = "Authorization: Basic " & base64(ID & ":" & pas) & vbCrLf
objIE.navigate2 strURL, , , , strHEAD
'表示終了まで待つ
Do While objIE.Busy = True
'何もしないループ(笑)
DoEvents
Loop
'エクセルで基本認証済みのものを横取り?
'IE側は中の表示がない同名?の窓が出てくる
Workbooks.Open strURL
'ただ以前対象のファイルが開かれた事があったりすると
  'IE側で先に開かれてOpenメソッドが失敗しましたとなる
End Sub

実験用に基本認証でくくられている場所に有るcsvファイルを用意できればいいのですが・・・

投稿時間:2006/05/02(Tue) 16:35
投稿者名:Ken3(管理者)
Eメール:
URL :
タイトル:
基本認証 csvファイル XMLHTTPでダウンロードしてみては?
ごめんなさい、真逆だったのですね。
※私の回答はIEで開けない時?で、質問はIEで開かせたくない、Excel内で開きたいでしたか・・・

基本認証の.csvを一時的にローカルファイルにダウンロードして、
Workbooks.Open "c:\temp.csv"
で開こうと思い、少しチャレンジしてみました。

パターン的にサンプルがほしい時は、
site:www.microsoft.com Web 基本認証 "End Sub"
と
キーワードを書いた後に、"End Sub"で探すとよくサンプルが見つかります。
※VBAやVBのプログラムはSub 〜 End Sub なので。

XML と Exchange 2000 による Web アプリケーション開発
http://www.microsoft.com/japan/msdn/exchange/exchange2000/devwebapps.asp
で
XMLHTTP によるコードの記述
XMLHTTP .OPEN があることを知る。

で次に、
site:www.microsoft.com xmlhttp open

Web ページがアクセス可能かどうかを確認する方法はありますか
http://www.microsoft.com/japan/technet/scriptcenter/resources/qanda/feb05/hey0222.mspx

Set objHTTP = CreateObject("MSXML2.XMLHTTP") 
objHTTP.Open "GET", strURL, FALSE
objHTTP.Send

Wscript.Echo(objHTTP.statusText)

とか

Set objHTTP = CreateObject("MSXML2.XMLHTTP") 
objHTTP.Open "GET", strURL, FALSE
objHTTP.Send

Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objFile = objFSO.CreateTextFile("script_center.htm", ForWriting)
objFile.Write objHTTP.ResponseText
objFile.Close

なんて感じで、何か保存してますね。

次は、MSXML2.XMLHTTPの詳細が知りたいです。
※基本認証可能か?知りたいです。

site:www.microsoft.com XMLHTTP .Open .Send

[HOWTO] XMLHTTP を使用してバイナリ ストリームを送信する方法
http://support.microsoft.com/default.aspx?scid=kb;ja;296772
ここに、
.setRequestHeader
とヘッダー情報のセットが載っていたりする。。。

さてと、
Sub cccc()

    Dim objIE As Object 'IEオブジェクト参照用

    'インターネットエクスプローラーのオブジェクトを作る
    Set objIE = CreateObject("InternetExplorer.application")
    objIE.Visible = True '見えるようにする(お約束)

    'テスト用の認証ページに飛ぶ
    Const strURL = "http://www.kurokiya.sake-ten.jp/zzz/test.csv"
    Const strHEAD = "Authorization: Basic bWFpbG1hZ2E6Z3Vlc3Q= " & vbCrLf

    objIE.navigate2 strURL, , , , strHEAD

    '表示終了まで待つ
    Do While objIE.Busy = True
        '何もしないループ(笑)
        DoEvents
    Loop

    'XMLHTTPでローカルにダウンロードする
    Dim objHTTP As Object
    
    Set objHTTP = CreateObject("MSXML2.XMLHTTP")
    objHTTP.Open "GET", strURL, False
    objHTTP.setRequestHeader "Authorization", " Basic bWFpbG1hZ2E6Z3Vlc3Q= " & vbCrLf
    objHTTP.Send

    MsgBox objHTTP.ResponseText

End Sub

とする、それらしく画面に出た・・と思ったら文字化けしてる・・・
objHTTP.ResponseText
を保存して開きたいよなぁ。もしくはobjHTTP.ResponseTextを直接シートに貼り付けたいんだけどなぁ・・・

> 実験用に基本認証でくくられている場所に有るcsvファイルを用意できればいいのですが・・・

私の通販用のサイトですが、
    Const strURL = "http://www.kurokiya.sake-ten.jp/zzz/test.csv"
    Const strHEAD = "Authorization: Basic bWFpbG1hZ2E6Z3Vlc3Q= " & vbCrLf
ここ上記の値でテストで使ってみてください。

もしソースをUPする時は、今回みたいに気をつけてくださいね。※本番用CODEをUPしないでね。

文字コードの件、少々探ってみます。

途中経過ですが、何かの参考となれば幸いです。

投稿時間:2006/05/02(Tue) 18:22
投稿者名:Ken3(管理者)
Eメール:
URL :
タイトル:
Re^3: 基本認証とcsvファイル
下記のような感じで、一時csvをローカルに保存して、
開いてみました。

Sub dddd()

    Dim objIE As Object 'IEオブジェクト参照用

    'インターネットエクスプローラーのオブジェクトを作る
    Set objIE = CreateObject("InternetExplorer.application")
    objIE.Visible = True '見えるようにする(お約束)

    'テスト用の認証ページに飛ぶ
    Const strURL = "http://www.kurokiya.sake-ten.jp/zzz/test.csv"
    Const strHEAD = "Authorization: Basic bWFpbG1hZ2E6Z3Vlc3Q= " & vbCrLf

    objIE.navigate2 strURL, , , , strHEAD

    '表示終了まで待つ
    Do While objIE.Busy = True
        '何もしないループ(笑)
        DoEvents
    Loop

    'XMLHTTPでローカルにダウンロードする
    Dim objHTTP As Object
    
    Set objHTTP = CreateObject("MSXML2.XMLHTTP")
    
    objHTTP.Open "GET", strURL, False  'URLとモードを教えてあげる
    
    'ヘッダー情報を送る  :(コロン)が入っていないことに注意・・これでハマった。
    objHTTP.setRequestHeader "Content-Type", " text/xml; charset=UTF-8 "
    objHTTP.setRequestHeader "Authorization", " Basic bWFpbG1hZ2E6Z3Vlc3Q= " & vbCrLf
    '↑Authorization:のコロンは必要なし・・・
    
    objHTTP.Send  'ここでデータがサーバーへ送られる と 同時にレスポンスが返る??
    'ここに読めなかったときのエラー処理を書きたいが・・・どうする???

    'メモリに読み込めたら、ファイルに落としたいので、
    'ADODB.Stream で 読み込んだデータを書き込む
    Const adTypeBinary = 1
    Const adSaveCreateOverWrite = 2

    Dim objA As Object  'ADODB.Stream
    Dim strFILENAME As String  'ファイル名
    
    strFILENAME = ActiveWorkbook.Path & "\tmp.csv" '現在のブック+tmp.csvとする
    
    Set objA = CreateObject("ADODB.Stream")
    objA.Type = adTypeBinary
    objA.Open
    objA.Write objHTTP.responseBody  'Streamに本文をそのまま代入
    'そしてファイル.SaveToFileで書き込む
    objA.SaveToFile strFILENAME, adSaveCreateOverWrite
    '後始末
    objA.Close  '開けたら閉めようね。
    Set objADOS = Nothing  '変数も後始末
    Set objHTTP = Nothing  'XMLオブジェクトも用なし
    objIE.Quit 'IEも用済みなので消えてもらう
    Set objIE = Nothing  '変数も後始末

    'やっとテンポラリができたので、
    'ローカルに落ちたcsvをOpenする
    Workbooks.Open strFILENAME  'テンポラリのCSVを開きます

End Sub

もし、使えるようなら、エラー処理や一時ファイルの削除など肉付けをして使ってみてください。

何かの参考となれば幸いです。

投稿時間:2006/05/02(Tue) 18:29
投稿者名:Ken3(管理者)
Eメール:
URL :
タイトル:
Re^4: 基本認証とcsvファイル
あっヤバイ
CreateObject("ADODB.Stream")
がWin98だと使えないや・・・
UPしたコードは忘れてください(笑)

投稿時間:2006/05/02(Tue) 18:38
投稿者名:Ken3(管理者)
Eメール:
URL :
タイトル:
Re^4: 基本認証とcsvファイル
よく考えたらobjIEとか必要なかった・・・スミマセン。

Sub eeee()

    'XMLHTTPでローカルにダウンロードする
    Dim objHTTP As Object
    Const strURL = "http://www.kurokiya.sake-ten.jp/zzz/test.csv"
    
    Set objHTTP = CreateObject("MSXML2.XMLHTTP")
    
    objHTTP.Open "GET", strURL, False  'URLとモードを教えてあげる
    
    'ヘッダー情報を送る  :(コロン)が入っていないことに注意・・これでハマった。
    objHTTP.setRequestHeader "Content-Type", " text/xml; charset=UTF-8 "
    objHTTP.setRequestHeader "Authorization", " Basic bWFpbG1hZ2E6Z3Vlc3Q= " & vbCrLf
    '↑Authorization:のコロンは必要なし・・・
    
    objHTTP.Send  'ここでデータがサーバーへ送られる と 同時にレスポンスが返る??
    'ここに読めなかったときのエラー処理を書きたいが・・・どうする???

    'メモリに読み込めたら、ファイルに落としたいので、
    'ADODB.Stream で 読み込んだデータを書き込む
    Const adTypeBinary = 1
    Const adSaveCreateOverWrite = 2

    Dim objA As Object  'ADODB.Stream
    Dim strFILENAME As String  'ファイル名
    
    strFILENAME = ActiveWorkbook.Path & "\tmp.csv" '現在のブック+tmp.csvとする
    
    Set objA = CreateObject("ADODB.Stream")
    objA.Type = adTypeBinary
    objA.Open
    objA.Write objHTTP.responseBody  'Streamに本文をそのまま代入
    'そしてファイル.SaveToFileで書き込む
    objA.SaveToFile strFILENAME, adSaveCreateOverWrite
    '後始末
    objA.Close  '開けたら閉めようね。
    Set objADOS = Nothing  '変数も後始末
    Set objHTTP = Nothing  'XMLオブジェクトも用なし
    
    'やっとテンポラリができたので、
    'ローカルに落ちたcsvをOpenする
    Workbooks.Open strFILENAME  'テンポラリのCSVを開きます

End Sub

Win98と2000/XPでプログラムが切り替えられれば、、、う〜ん。。。

投稿時間:2006/05/02(Tue) 19:19
投稿者名:
Eメール:
URL :
タイトル:
回答有難うございます
解答していただいたものをもとに一週間ほど調べたり考えたりしたいと思います。

有難うございました。


ページフッター リンクや広告、質問送信など

三流解説を読んでいただき、どうもです。ここから下は、三流君宛のメッセージ送信や 三流君のホームページの紹介・案内です
目的の情報が見つかったか?少々心配しつつ、、、※質問や感想は、気軽に送ってくださいね。

[三流君 VBAでWebBrowser IEを操作する] / [三流君 VBAで楽しくプログラミング] / [AB型の変わり者 三流プログラマー Ken3 三流君Top]

大分類:[Document.Forms(入力処理)] / [Document.Links(リンク情報)] / [Document.Images(画像情報)] / [Document.Frames(フレーム処理)]
サンプル・例題:[過去のメルマガ記事一覧] / [少し大きなIE操作サンプル] / [小さなコードでIE操作の動作確認]

F1でヘルプを見たり、デバック時にDebug.Print使ったり、イミディエイト ウインドウで簡単な確認したり。
なれると当たり前に操作している方法が↓かなぁ。
[F1ヘルプ マクロ記録ほか]・・・基本のF1を押してヘルプを見る方法など
[実行時エラー、デバッグモード]・・・デバッグの流れを簡単に(ハマった時はツライけど)
[イミディエイト ウインドウ と Debug.Print]・・・プログラム作成時に便利なイミディエイト ウインドウ
[VBA ウォッチ式とSTOPを使ってみた]・・・STOPで止め、ウォッチ式でオブジェクトの中身を確認する方法など
[参照設定のお話]・・・設定すると便利な(設定しないと使えない)、参照設定のお話

項目別に↓にプログラマーの本音?それとも建て前?的な記事をまとめました。お探しのジャンルを選択してください。
[プログラムは心? spirit]・・・プログラマー 心・気質・魂
[学ぶ study]・・・学習、技術の取得
[仕様書 doc]・・・仕様書・設計書関係の話

項目別に↓に人気の記事をまとめてみました。お探しのジャンルを選択してください。
[VBAでIE ウェブブラウザーを操作]・・・VBAでIE,WebBrowserを操作する サンプルです
[MSアクセス から エクセル を呼ぶ Excel.Application]・・・AccessからExcelを操作したりデータの書き出しなどです
[アウトルック メールの操作 Outlook.Application]・・・VBAからOutlookを使い、メール関係を処理するサンプルです
↑上記3つみたいなCreateObjectで他のアプリケーションを操作するサンプルが人気です。

Excel関係:
[エクセル ユーザーフォームを操作する]・・・エクセルでユーザーフォームを作成して入力などを行ってます
[エクセルからアクセスを操作する]・・・ExcelからAccessのマクロを起動してみました、
[エクセル関係 関数、その他]・・・その他Excel関係です

Access関係:
[アクセス ユーザーフォーム/サブフォーム 操作]・・・アクセスでフォームを使ったサンプルです
[アクセス レポート操作]・・・レポートを操作してみました
[アクセス クエリーやその他関数]・・・あまりまとまってませんが、スポット的な単体関数の解説です

その他:VBAの共通関数やテキストファイルの操作など
[テキストファイルの操作(Open,Close,Print,Input)]・・・普通のテキストファイルを使ったサンプルです

Blog:[三流君の作業日記]/ [objIEを使用したサンプルコードを見る]/ 広告-[通販人気商品の足跡]

質問や要望など メッセージを送る(三流君に連絡する)

三流プログラマーのKen3 が 皆さんの質問にお答えします
と カッコつけて言っても、実力不足ですべての質問に回答することはできないのが現実なのですが、できる範囲で 三流的な逃げ手 や 解決方法 を探します(回答します)。

感想や質問・要望・苦情など 三流君へメッセージを送る。
時間的余裕のある要望・質問・苦情の場合は、下記のフォームからメッセージを送ることができます。

あなたのお名前(ニックネーム):さん
返信は?: 不用(HP更新を待つ) , E-mail→ アドレス:に返事をもらいたい



(感想や質問・要望 メッセージはHPで記事に載せることがあります。)

急ぎで連絡がほしい、そんな時は:[三流君連絡先]に連絡してください。



[トップページへ 戻る] / [VBA TOP] / [WebBrowser IEの操作 TOPへ]