三流君 Outlook Contact 連絡先・アドレス帳を操作する

'VBSからOutlook 連絡先に１つアイテムを作成する
'入力された名前とアドレスで連絡先のアイテムを1つ作成する

'テストデータをInputBoxで手入力
Dim strNAME  '名前の姓
Dim strYOMI  'フリガナ
Dim strEMAIL 'メールアドレス

strNAME = InputBox("お名前 姓は")          '入力させる
strYOMI = InputBox("読み方、フリガナは？") '入力させる
strEMAIL = InputBox("メールアドレスは？", "test@test.test") '入力させる

'Outlook.Applicationの起動 

    Dim oApp        'As Outlook.Application OutlookのApplication オブジェクトを入れる
    Dim myNameSpace 'As Outlook.NameSpace 名前のスペースと言われても、、
    Dim myFolder    'As Outlook.Folder フォルダー指定

    'outlook 起動をCreateObjectで ※これだと複数起動してしまうがご勘弁を
    Set oApp = CreateObject("Outlook.Application")

    '呪文１ 名前空間 の 指定 と言っても、.GetNamespace("MAPI")しただけ
    Set myNameSpace = oApp.GetNamespace("MAPI")

'olFolderContacts 10 連絡先フォルダ
    '次は作業フォルダーの指定(.GetDefaultFolder) と 表示(.Display)
    Set myFolder = myNameSpace.GetDefaultFolder(10) '規定のフォルダー olFolderContacts=10 指定
    myFolder.Display  '表示 いつものクセで .Visible = True とやりがちだけど

    '通常サイズ olNormalWindow=2 で表示(ほかに olMaximized=0,olMinimized=1)
    oApp.ActiveWindow.WindowState = 2   'olNormalWindow=2 を セット

'ここから連絡先の作成
'As Outlook.ContactItem 連絡先のアイテム を 作成する
'CreateItem(2) とolContactItem=2 2を指定しただけ。

    Dim cITEM   'As Outlook.ContactItem  '連絡先アイテム
    
    'CreateItemで連絡先の作成
    Set cITEM = oApp.CreateItem(2)   'olContactItem=2 2連絡先を指定
    
    cITEM.Display   '編集画面表示
    
    'データのセット
    cITEM.Email1Address = strEMAIL   'メールアドレス1
    cITEM.YomiCompanyName = "カブシキガイシャ アイウエオ"
    cITEM.CompanyName = "株式会社アイウエオ"
     
    cITEM.YomiLastName = strYOMI  'フリガナをセット
    cITEM.LastName = strNAME      '姓をセット
    'cITEM.YomiFirstName          '名前のフリガナ
    'cITEM.FirstName              '名
         '↑他にも 値、プロパティがあるけど、テストで表示
    '動作

    'cITEM.Save   '.Saveで保存 .Close時に下記みたいに閉じると同時に保存も可能
    cITEM.Close 0 '保存して閉じる olSave=0  olDiscard=1 olPromptForSave=2