[三流君] −−＞ [ＡＳＰで遊ぶ、失敗する] −−＞ [バックナンバー一覧]
−−＞ No.032 SQL DELETE文でデータを削除してみた

SQL DELETE文でデータを削除してみた

本文(発行内容)

＜SQL DELETE文でデータを削除してみた＞

こんにちは、Ｋｅｎ３です。

今回は、またまたＳＱＬ文で、
Ｄｅｌｅｔｅ文で
DateAdd関数で日付や時間の計算
をしてみたいと思います。

と言っても、たいしたことないのでご安心を。

/*
 * １．文法は簡単 
*/

書き方は、なんか一番簡単で、
Delete Form テーブル名 Where 条件
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
で、ＯＫです。

なんかあっけないよね。

/*
 * ２．よく見かけるＩＤフィールド
*/

データベース名:db029.mdb
テーブル名:KANSOU
フィールド
ID        オートナンバー型
F_KUBUN   テキスト型  ASP,VBA,GUCHI,24Hと４つの区分
F_NO      整数型      0:は全体に対して、１〜はＸ話にする
F_MEMO    テキスト型  一言メッセージ
WriteTime 日付型      書き込み日付

なんてデータベースを使用してます。

フィールドには、ＩＤ，ＮＯ，ＣＯＤＥなどよくみかけますよね。
これは、まだやってないけどマスターと明細テーブルをつなげたり、
１件のデータを特定して削除する時に使います。

IDが５番のデータを削除するには、
Delete From KANSOU Where ID = 5
とＳＱＬを発行します。

３日前のデータを削除するには、
Delete From KANSOU Where WriteTime <= #日付#
とＳＱＬを発行します。

削除するには、テーブルと条件を頭に思い浮かべれば、なんか出来そうですね。

/*
 * ３．削除データのボタンを作る
*/
データを一覧表示して、横に削除のボタンを付けて処理を行います。

簡単な仕様
test032-1.asp
で、
データの一覧表示と削除ボタンを付ける
ボタンが押されたら、test032-2.asp削除処理を呼ぶ

test032-2.asp
フィールドの隠し項目で削除するＩＤを受け取ったら、
ＳＱＬのDelete文を発行する。

この、表示・選択（test032-1）と削除実行部（test032-2）を作成します。

-- test032-1.asp
ここでは、データの一覧表示と削除ボタンのフォームを作ります
<%@LANGUAGE=VBScript%>
<html>
<head>
<title>フォームに削除のボタンを作成します</title>
</head>
<body>
<h2>フォームに削除のボタンを作成します</h2>
test032-1.asp<br>
<hr>
<%  '関数をコールする
    Call TEST_MAKE_DATA()
%>
<HR>
終了です。<br>
<A href="test029-1.asp">データ確認と登録</a><br>

</body>
</html>

<% 'データ表示と削除ボタン生成
Sub TEST_MAKE_DATA()

  'ADO DB Connection オブジェクトを作成する、英文そのままじゃん
  Set db=Server.CreateObject("ADODB.Connection")

  '.Provider？プロバイダー？通信会社？じゃなくって
  'データアクセスにはJet.OLEDB.4.0を使うことを設定
  db.Provider = "Microsoft.Jet.OLEDB.4.0"

  '次に、接続ＤＢの位置を渡すので、Server.MapPathで変換して渡す
  db.ConnectionString = Server.MapPath("db029.mdb")

  'やっとデータベースを開ける
  db.open

  'SQL文を作る
  strSQL = "Select * From KANSOU "  '感想(KANSOU)テーブルから全項目(*)セレクト
  strSQL = strSQL & "ORDER BY WriteTime DESC"              '並べ替えは時間の降順

  'お約束のレコードセットの作成 SQL文の発行
  Set rs = db.Execute(strSQL)

  'データの表示をテーブルで行う
  Response.Write "<TABLE Border='1'>"

  '見出しをバカっぽく、そのまま書き込む
  Response.Write "<TR>"
  Response.Write "<TD>アクション</TD>"
  Response.Write "<TD>日付</TD>"
  Response.Write "<TD>区分</TD>"
  Response.Write "<TD>NO.</TD>"
  Response.Write "<TD>感想</TD>"
  Response.Write "</TR>"

  'お約束のＥＯＦまでループは(データが無くなるまでループ)、
  Do While rs.EOF = False   'レコードセットの.EOFがFalseの間
    Response.Write "<TR>"   '内容を表示する、行開始のタグ＜ＴＲ＞
    'フォームを作成する
    Response.Write "<TD><FORM ACTION='test032-2.asp' METHOD='POST'>"
       'IDを隠し項目(DELETE_ID)にする
    Response.Write "<INPUT type='hidden' NAME='DELETE_ID' VALUE='"
    Response.Write rs.Fields.Item("ID") & "'>" 
       'ボタンは普通に作成する
    Response.Write "<INPUT TYPE='submit' VALUE='削除'>"
    Response.Write "</FORM></TD>"
    '中身を表示
    Response.Write "<TD>" & rs.Fields.Item("WriteTime") & "</TD>"
    Response.Write "<TD>" & rs.Fields.Item("F_KUBUN") & "</TD>"
    If rs.Fields.Item("F_NO") = 0 Then '0の全体かチェック
      Response.Write "<TD>全体</TD>"
    Else
      Response.Write "<TD>" & rs.Fields.Item("F_NO") & "</TD>" 'NO表示
    End If
    Response.Write "<TD>" & rs.Fields.Item("F_MEMO") & "</TD>"
    Response.Write "</TR>"
    '次のレコードにポインタを移動する
    rs.MoveNext    'これを忘れると悲惨なことに、、、
  Loop

  Response.Write "</TABLE>"  'テーブルは終わりです

  '開いていたレコードセットを閉じる
  rs.Close

  'データベースも閉じようよ
  db.Close

  'お行儀よくオブジェクトも開放しましょう（通常は自動的に解放されるけど）
  Set db = Nothing

End Sub
%>

ポイントは、
^^^^^^^^^^^
    'フォームを作成する
    Response.Write "<TD><FORM ACTION='test032-2.asp' METHOD='POST'>"
       'IDを隠し項目(DELETE_ID)にする
    Response.Write "<INPUT type='hidden' NAME='DELETE_ID' VALUE='"
    Response.Write rs.Fields.Item("ID") & "'>" 
       'ボタンは普通に作成する
    Response.Write "<INPUT TYPE='submit' VALUE='削除'>"
    Response.Write "</FORM></TD>"
の
Response.Write "<INPUT type='hidden' NAME='DELETE_ID' VALUE='"
Response.Write rs.Fields.Item("ID") & "'>" 
２行で、
type='hidden'を使用して隠し項目に、
VALUEでＩＤを保存し、
削除ボタンが押されたら、
ACTION='test032-2.asp'
へデータが渡ります。

-- test032-2.asp
さて、データが渡ってきてからの処理ですね。
<%@LANGUAGE=VBScript%>
<html>
<head>
<title>削除のＳＱＬ DELETE文を発行する</title>
</head>
<body>
<h2>削除のＳＱＬ DELETE文を発行する</h2>
test032-2.asp<br>
<hr>
<%  '関数をコールする
    Call TEST_DELETE_DATA()
%>
<HR>
終了です。<br>
<A href="test032-1.asp">再度削除選択処理へ</a><br>
<A href="test029-1.asp">データ確認と登録</a><br>

</body>
</html>

<% '削除処理
Sub TEST_DELETE_DATA()

  'ADO DB Connection オブジェクトを作成する、英文そのままじゃん
  Set db=Server.CreateObject("ADODB.Connection")
  '.Provider？プロバイダー？通信会社？じゃなくって
  'データアクセスにはJet.OLEDB.4.0を使うことを設定
  db.Provider = "Microsoft.Jet.OLEDB.4.0"
  '次に、接続ＤＢの位置を渡すので、Server.MapPathで変換して渡す
  db.ConnectionString = Server.MapPath("db029.mdb")
  'やっとデータベースを開ける
  db.open

  'IDを条件にSQL DELETE文を作る
  strSQL = "DELETE From KANSOU "  '感想(KANSOU)テーブルを削除するので
  strSQL = strSQL & " Where ID=" & Request.Form("DELETE_ID")

  '中身を表示する
  Response.Write "発行するSQLは[" & strSQL & "]です"

  'SQL文の発行
  db.Execute(strSQL)

  'データベースも閉じようよ
  db.Close
  'お行儀よくオブジェクトも開放しましょう（通常は自動的に解放されるけど）
  Set db = Nothing

End Sub
%>

ポイントは、
^^^^^^^^^^^
  'IDを条件にSQL DELETE文を作る
  strSQL = "DELETE From KANSOU "  '感想(KANSOU)テーブルを削除するので
  strSQL = strSQL & " Where ID=" & Request.Form("DELETE_ID")
で
Request.Form("DELETE_ID")の隠し項目で送られて来たデータを使用して、
DELETE文を作成してます。

  '中身を表示する
  Response.Write "発行するSQLは[" & strSQL & "]です"
まぁ、そのまま終わってしまうと味気ないので、表示してます

  'SQL文の発行
  db.Execute(strSQL)
作成したＳＱＬ文を.Executeで発行します。

テストは、
http://www.ken3.org/cgi-bin/test/test032-1.asp
で確認可能です。
データ遠慮無く壊して遊んでください。
データ少なくなってきたら、
http://www.ken3.org/cgi-bin/test/test029-1.asp
で追加しながら、テストして下さい。

/*
 * ４．終わりの挨拶
*/

今回は、軽く、SQLのDELETE文でした。
残るは、更新関係のＵＰＤＡＴＥ文ですね。
そろそろＳＱＬも軽く？感じてきましたか？

えっ、入り口しかやってないのに偉そう？だって。
う〜ん、奥が深そうだからなぁＳＱＬって。

単体じゃなく、そろそろつなげて１本作りたいですね。
そんな話しの続きは（自分のメルマガ宣伝）
http://www.ken3.org/backno/backno_guchi28.html#142
で、[トンネルの話、貫通後、横に広げるのは簡単？]
といいかげんなこと書いてます。お時間のある人は見て笑ってください。

ＡＳＰ、ＶＢＳｃｒｉｐｔ勉強中の三流プログラマーのＫｅｎ３でした。

ページフッター

ここまで、読んでいただきどうもです。目的の情報が見つかったか？少々心配しつつ、、、

三流君へ メッセージを送る

感想や質問・要望・苦情など 三流君へメッセージを送る。
返信例 XXXXさんへ
下記のフォームからメッセージを送ることができます。

あなたのお名前（ニックネーム）:さん
返信は？:

アドレス:に返事をもらいたい
感想や質問↓:


(感想や質問・要望・苦情はHPで記事に載せることがあります。)

種類別のリンク や 広告など

[三流君(TOP ken3.org へ戻る)] / [ASPで遊ぶ、失敗する] / [ASP記事 バックナンバー目次]

Blogとリンク:[三流君のMemo別館]/ [ASP 三流君のソースコード置き場]/ [Ken3Video YouTubeで動画解説]
広告:

気になった ジャンル ↓を選択してください。

まぁ、基本はデータの受け取りかなぁ。
・[Form等を使用したデータのやり取り]・・・ASPと言っても、HTMLの入力フォームからデータを受け取ります。POSTやGETでやりとりを押さえますか。

次は、データの入出力 で ADOを使った(ADOで接続) と SQLの解説を少々
・[ADOでMdbファイルを使う]・・・MDBと接続して、簡単な追加・更新・削除を行った。
・[ADOでExcelと接続してみた]・・・.xlsと接続してSQLを使ってみた。
・[ADOでCSVと接続してみた]・・・.CSV テキストを読み出した。※更新・削除はできません

広告:

DBが使えるので、あまり使用しないけど、普通のテキストファイル処理
・[テキストファイル処理]・・・ファイルを開いて、書き込む。１行読み込みなどを軽く

VBScriptでFormat関数が無いなど、微妙にVBAと違うけど
[VBScript関数関係の説明]・・・少し、処理を書いてみた。
[その他処理サンプル]・・・あまり良いサンプル作れなかったけど。。。
何かの参考となれば幸いです。


[三流君(TOP ken3.org へ戻る)] / [ASPで遊ぶ、失敗する] / [ASP記事 バックナンバー目次]

広告: